//Stereogram test #3
//(C) 2004 Haruka Kataoka

FollowBall fbarr[], mouseb;
float phase = 0.0;
float v = 0.2;
int number = 50;
float mx, my, mz;
boolean isEnableSize;

void setup() {
	size(500, 300);
	mouseb = new FollowBall();
	fbarr = new FollowBall[number];
	for (int i=0; i<number; i++) {
		fbarr[i] = new FollowBall();
	}
	framerate(24);
	background(0, 0, 0);
	ellipseMode(CENTER_DIAMETER);
	//noCursor();
	isEnableSize = false;
}

void loop() {
	//mouse x,y,z
	mx = (float)(mouseX - ((mouseX>=250)?350:150));
	my = (float)(mouseY - 150);
	if (mx >  100.0) mx =  100.0;
	if (mx < -100.0) mx = -100.0;
	if (my >  100.0) my =  100.0;
	if (my < -100.0) my = -100.0;
	mz = 50.0*(cos(mx/100*PI) - cos(my/100*PI));
	mouseb.set(mx, my, mz);
	//follow mouse
	for (int i=0; i<number; i++) {
		fbarr[i].follow(mx , my, mz);
	}
	//draw balls
	background(255, 255, 255);
	fill(127, 255, 255);
	noStroke();
	for (int i=0; i<number; i++)
		fbarr[i].display(isEnableSize);
	noFill();
	stroke(0, 255, 0);
	mouseb.display(isEnableSize);
}

void mousePressed() {
	isEnableSize = !isEnableSize;
}

//class  FollowBall
class FollowBall {
	float x, y, z;
	float vx, vy, vz;
	float size;
	float follow; //follow target
	float distance = 200; //distance from eye
	float parallax = 40.0;//default parallax
	float resistance;//air resistance
	
	//Constructor
	FollowBall () {
		reset();
		vx = vy = vz = 0.0;
	}
	
	//Reset Amplitude
	void reset() {
		follow = random(0.1, 1.0);
		resistance = follow * random(0.001, 0.05);
		x = random(-100, 100);
		y = random(-100, 100);
		z = random(-100, 100);
		size = 20;
	}
	
	//follow target tx,ty,tz
	void follow(float tx, float ty, float tz) {
		float px = tx - x;
		float py = ty - y;
		float pz = tz - z;
		float d = sqrt(px*px + py*py + pz*pz);
		vx += follow * (px / d) - resistance * vx;
		vy += follow * (py / d) - resistance * vy;
		vz += follow * (pz / d) - resistance * vz;
		x += vx;
		y += vy;
		z += vz;
	}
	//set x,y,z
	void set(float ax, float ay, float az) {
		x = ax;
		y = ay;
		z = az;
	}
	
	//display
	void display(boolean isSize) {
		if ((distance+z) < distance/5) return;
		float r = distance / (distance+z);//display size rate
		//display x, y, size and parallax
		int dsize = (isSize) ? (int)(size * r) : (int)size;
		int dx = (int)(x * r);
		int dy = (int)(y * r);
		if (abs(dx) > 200 || abs(dy) > 200) return;
		int dp = (int)((parallax * r - parallax)/2.0);
		ellipse(dx+150+dp, dy+150, dsize, dsize);// left image
		ellipse(dx+350-dp, dy+150, dsize, dsize);// right image
	}
}